; Installer di TieMeasureFlow (TieMeasureFlow#76).
; Cosa fa: copia la cartella standalone di Nuitka in Program Files\Tielogic\TieMeasureFlow,
; crea in ProgramData le cartelle scrivibili da tutti gli utenti (licenze, uploads, camera, log)
; e i collegamenti in menu Start e sul desktop.
; Come si usa: lo lancia build.ps1 con /DVersione /DVersione4 /DOrigine /DUscita; a mano:
;   ISCC /DVersione=3.0.0 /DVersione4=3.0.0.0 /DOrigine=build\nuitka\avvio.dist /DUscita=dist TieMeasureFlow.iss
; Setup silenzioso: TieMeasureFlow-setup-X.exe /VERYSILENT /SUPPRESSMSGBOXES /NORESTART
; (/CURRENTUSER per installare senza amministratore, in %LOCALAPPDATA%\Programs).
; ATTENZIONE: la licenza NON e' nel setup: va copiata in {commonappdata}\Tielogic\licenze\tiemeasureflow.json
; (la cartella e' scrivibile dagli utenti). La disinstallazione lascia licenze, database (tmf.db),
; uploads e config.env: sono dati del cliente.

#ifndef Versione
  #define Versione "0.0.0"
#endif
#ifndef Versione4
  #define Versione4 "0.0.0.0"
#endif
#ifndef Origine
  #define Origine "..\..\build\nuitka\avvio.dist"
#endif
#ifndef Uscita
  #define Uscita "..\..\dist"
#endif

[Setup]
; AppId proprio di TieMeasureFlow (diverso da quello di TieVision Studio)
AppId={{B7D4E2A1-5C93-4F6E-8A0B-3D1F7E9C2A64}
AppName=TieMeasureFlow
AppVersion={#Versione}
AppVerName=TieMeasureFlow {#Versione}
AppPublisher=Tielogic
DefaultDirName={autopf}\Tielogic\TieMeasureFlow
DefaultGroupName=Tielogic\TieMeasureFlow
PrivilegesRequired=admin
; /CURRENTUSER solo da riga di comando: serve alle prove senza amministratore
PrivilegesRequiredOverridesAllowed=commandline
ArchitecturesAllowed=x64compatible
ArchitecturesInstallIn64BitMode=x64compatible
OutputDir={#Uscita}
OutputBaseFilename=TieMeasureFlow-setup-{#Versione}
SetupIconFile=TieMeasureFlow.ico
UninstallDisplayIcon={app}\TieMeasureFlow.exe
VersionInfoVersion={#Versione4}
VersionInfoCompany=Tielogic
VersionInfoProductName=TieMeasureFlow
Compression=lzma2/max
SolidCompression=yes
WizardStyle=modern
DisableProgramGroupPage=yes
; il programma in esecuzione tiene aperti i file: Inno chiede di chiuderlo (in silenzioso lo chiude)
CloseApplications=yes

[Languages]
Name: "italiano"; MessagesFile: "compiler:Languages\Italian.isl"

[Tasks]
Name: "desktopicon"; Description: "Crea un collegamento sul desktop"; GroupDescription: "Collegamenti:"

[Dirs]
; scrivibili da tutti gli utenti: l'exe gira con l'utente che lo lancia, non con admin
Name: "{commonappdata}\Tielogic\licenze"; Permissions: users-modify
Name: "{commonappdata}\Tielogic\TieMeasureFlow"; Permissions: users-modify
Name: "{commonappdata}\Tielogic\TieMeasureFlow\uploads"; Permissions: users-modify
Name: "{commonappdata}\Tielogic\TieMeasureFlow\camera"; Permissions: users-modify
Name: "{commonappdata}\Tielogic\TieMeasureFlow\log"; Permissions: users-modify

[Files]
Source: "{#Origine}\*"; DestDir: "{app}"; Flags: recursesubdirs createallsubdirs ignoreversion

[Icons]
Name: "{group}\TieMeasureFlow"; Filename: "{app}\TieMeasureFlow.exe"
Name: "{group}\Impronta di questo computer"; Filename: "{app}\TieMeasureFlow.exe"; Parameters: "--impronta"
; l'exe non ha finestra: per fermarlo si chiude il processo
Name: "{group}\Arresta TieMeasureFlow"; Filename: "{sys}\taskkill.exe"; Parameters: "/IM TieMeasureFlow.exe /F"; Flags: runminimized
Name: "{group}\Cartella dati e configurazione"; Filename: "{commonappdata}\Tielogic\TieMeasureFlow"
Name: "{group}\Disinstalla TieMeasureFlow"; Filename: "{uninstallexe}"
Name: "{autodesktop}\TieMeasureFlow"; Filename: "{app}\TieMeasureFlow.exe"; Tasks: desktopicon

[Run]
Filename: "{app}\TieMeasureFlow.exe"; Description: "Avvia TieMeasureFlow"; Flags: nowait postinstall skipifsilent